<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN"
"http://www.w3.org/TR/html4/loose.dtd">
<html>
<meta name="GENERATOR" content="TtH 3.55">
<style type="text/css"> div.p { margin-top: 7pt;}</style>
<style type="text/css"><!--
td div.comp { margin-top: -0.6ex; margin-bottom: -1ex;}
td div.comb { margin-top: -0.6ex; margin-bottom: -.6ex;}
td div.hrcomp { line-height: 0.9; margin-top: -0.8ex; margin-bottom: -1ex;}
td div.norm {line-height:normal;}
span.roman {font-family: serif; font-style: normal; font-weight: normal;}
span.overacc2 {position: relative; left: .8em; top: -1.2ex;}
span.overacc1 {position: relative; left: .6em; top: -1.2ex;} --></style>
<title> Ambiguous Class Fusions in the GAP Character Table Library</title>
<h1 align="center">Ambiguous Class Fusions in the GAP Character Table Library </h1>
<body bgcolor="FFFFFF">
<div class="p"><!----></div>
<h3 align="center"> T<font size="-2">HOMAS</font> B<font size="-2">REUER</font> <br />
<i>Lehrstuhl D für Mathematik</i> <br />
<i>RWTH, 52056 Aachen, Germany</i> </h3>
<div class="p"><!----></div>
<h3 align="center">January 11th, 2004 </h3>
<div class="p"><!----></div>
<div class="p"><!----></div>
This is a collection of examples showing how class fusions between character
tables can be determined using the <font face="helvetica">GAP</font> system [<a href="#GAP4" name="CITEGAP4">GAP04</a>].
In each of these examples, the fusion is <em>ambiguous</em> in the sense that
the character tables do not determine it up to table automorphisms.
Our strategy is to compute first all possibilities with the <font face="helvetica">GAP</font> function
<tt>PossibleClassFusions</tt>, and then to use either other character tables or
information about the groups for excluding some of these candidates until
only one (orbit under table automorphisms) remains.
<div class="p"><!----></div>
The purpose of this writeup is twofold.
On the one hand, the computations are documented this way.
On the other hand, the <font face="helvetica">GAP</font> code shown for the examples can be used as
test input for automatic checking of the data and the functions used;
therefore, each example ends with a comparison of the result with the
fusion that is actually stored in
the <font face="helvetica">GAP</font> Character Table Library [<a href="#CTblLib" name="CITECTblLib">Bre04b</a>].
<div class="p"><!----></div>
<div class="p"><!----></div>
<h1>Contents </h1><a href="#tth_sEc1"
>1 Fusions Determined by Factorization through Intermediate Subgroups</a><br />
<a href="#tth_sEc1.1"
>1.1 Co<sub>3</sub>N5 → Co<sub>3</sub> (September 2002)</a><br />
<a href="#tth_sEc1.2"
>1.2 31:15 → B (March 2003)</a><br />
<a href="#tth_sEc1.3"
>1.3 SuzN3 → Suz (September 2002)</a><br />
<a href="#tth_sEc1.4"
>1.4 F<sub>3+</sub>N5 → F<sub>3+</sub> (March 2002)</a><br />
<a href="#tth_sEc2"
>2 Fusions Determined by Commutative Diagrams Using Smaller Subgroups</a><br />
<a href="#tth_sEc2.1"
>2.1 (A<sub>4</sub> ×O<sub>8</sub><sup>+</sup>(2).3).2 → Fi<sub>24</sub><sup>′</sup> (November 2002)</a><br />
<a href="#tth_sEc2.2"
>2.2 A<sub>6</sub> ×L<sub>2</sub>(8).3 → Fi<sub>24</sub><sup>′</sup> (November 2002)</a><br />
<a href="#tth_sEc3"
>3 Conditions Imposed by Brauer Tables</a><br />
<a href="#tth_sEc3.1"
>3.1 L<sub>2</sub>(16).4 → J<sub>3</sub>.2</a><br />
<a href="#tth_sEc3.2"
>3.2 L<sub>2</sub>(19) → J<sub>3</sub> (April 2003)</a><br />
<a href="#tth_sEc4"
>4 Fusions Determined by Information about the Groups</a><br />
<a href="#tth_sEc4.1"
>4.1 U<sub>3</sub>(3).2 → Fi<sub>24</sub><sup>′</sup> (November 2002)</a><br />
<a href="#tth_sEc4.2"
>4.2 L<sub>2</sub>(13).2 → Fi<sub>24</sub><sup>′</sup> (September 2002)</a><br />
<a href="#tth_sEc4.3"
>4.3 L<sub>2</sub>(17).2 → B (March 2004)</a><br />
<a href="#tth_sEc4.4"
>4.4 2<sup>3</sup>.L<sub>3</sub>(2) → G<sub>2</sub>(5)</a><br />
<a href="#tth_sEc4.5"
>4.5 The fusion from the character table of 7<sup>2</sup>:2L<sub>2</sub>(7).2 into the table of marks</a><br />
<div class="p"><!----></div>
<div class="p"><!----></div>
The examples use the <font face="helvetica">GAP</font> Character Table Library,
so we first load this package.
<div class="p"><!----></div>
<pre>
gap> LoadPackage( "ctbllib" );
true
</pre>
<div class="p"><!----></div>
<h2><a name="tth_sEc1">
1</a> Fusions Determined by Factorization through Intermediate Subgroups</h2>
<div class="p"><!----></div>
This situation clearly occurs only for nonmaximal subgroups.
Interesting examples are Sylow normalizers.
<div class="p"><!----></div>
<h3><a name="tth_sEc1.1">
1.1</a> Co<sub>3</sub>N5 → Co<sub>3</sub> (September 2002)</h3>
<div class="p"><!----></div>
Let H be the Sylow 5 normalizer in the sporadic simple group Co<sub>3</sub>.
The class fusion of H into Co<sub>3</sub> is not uniquely determined by the
character tables of the two groups.
<div class="p"><!----></div>
<pre>
gap> co3:= CharacterTable( "Co3" );
CharacterTable( "Co3" )
gap> h:= CharacterTable( "Co3N5" );
CharacterTable( "5^(1+2):(24:2)" )
gap> hfusco3:= PossibleClassFusions( h, co3 );;
gap> Length( RepresentativesFusions( h, hfusco3, co3 ) );
2
</pre>
<div class="p"><!----></div>
As H is not maximal in Co<sub>3</sub>, we look at those maximal subgroups of Co<sub>3</sub>
whose order is divisible by that of H.
<div class="p"><!----></div>
<pre>
gap> mx:= Maxes( co3 );
[ "McL.2", "HS", "U4(3).(2^2)_{133}", "M23", "3^5:(2xm11)", "2.S6(2)",
"U3(5).3.2", "3^1+4:4s6", "2^4.a8", "psl(3,4):d12", "2xm12",
"2^2.(2^7.3^2).s3", "s3xpsl(2,8).3", "a4xs5" ]
gap> maxes:= List( mx, CharacterTable );;
gap> filt:= Filtered( maxes, x -> Size( x ) mod Size( h ) = 0 );
[ CharacterTable( "McL.2" ), CharacterTable( "HS" ),
CharacterTable( "U3(5).3.2" ) ]
</pre>
<div class="p"><!----></div>
According to the A<font size="-2">TLAS</font> (see [<a href="#CCN85" name="CITECCN85">CCN<sup>+</sup>85</a>,pp. 34 and 100]),
H occurs as the Sylow 5 normalizer in U<sub>3</sub>(5).3.2 and in McL.2;
however, H is not a subgroup of HS,
since otherwise H would be contained in subgroups of type U<sub>3</sub>(5).2
(see [<a href="#CCN85" name="CITECCN85">CCN<sup>+</sup>85</a>,p. 80]), but the only possible subgroups
in these groups are too small (see [<a href="#CCN85" name="CITECCN85">CCN<sup>+</sup>85</a>,p. 34]).
<div class="p"><!----></div>
We compute the possible class fusions from H into McL.2
and from McL.2 to Co<sub>3</sub>, and then form the compositions of these maps.
<div class="p"><!----></div>
<pre>
gap> max:= filt[1];;
gap> hfusmax:= PossibleClassFusions( h, max );;
gap> maxfusco3:= PossibleClassFusions( max, co3 );;
gap> comp:= [];;
gap> for map1 in maxfusco3 do
> for map2 in hfusmax do
> AddSet( comp, CompositionMaps( map1, map2 ) );
> od;
> od;
gap> Length( comp );
2
gap> reps:= RepresentativesFusions( h, comp, co3 );
[ [ 1, 2, 3, 4, 8, 8, 7, 9, 10, 11, 17, 17, 19, 19, 22, 23, 27, 27, 30, 33,
34, 40, 40, 40, 40, 42 ] ]
</pre>
<div class="p"><!----></div>
So factoring through a maximal subgroup of type McL.2
determines the fusion from H to Co<sub>3</sub> uniquely up to table automorphisms.
<div class="p"><!----></div>
Alternatively, we can use the group U<sub>3</sub>(5).3.2 as intermediate
subgroup, which leads to the same result.
<div class="p"><!----></div>
<pre>
gap> max:= filt[3];;
gap> hfusmax:= PossibleClassFusions( h, max );;
gap> maxfusco3:= PossibleClassFusions( max, co3 );;
gap> comp:= [];;
gap> for map1 in maxfusco3 do
> for map2 in hfusmax do
> AddSet( comp, CompositionMaps( map1, map2 ) );
> od;
> od;
gap> reps2:= RepresentativesFusions( h, comp, co3 );;
gap> reps2 = reps;
true
</pre>
<div class="p"><!----></div>
Finally, we compare the result with the map that is stored on the library
table of H.
<div class="p"><!----></div>
<pre>
gap> GetFusionMap( h, co3 ) in reps;
true
</pre>
<div class="p"><!----></div>
<h3><a name="tth_sEc1.2">
1.2</a> 31:15 → B (March 2003)</h3>
<div class="p"><!----></div>
The Sylow 31 normalizer H in the sporadic simple group B
has the structure 31:15.
<div class="p"><!----></div>
<pre>
gap> b:= CharacterTable( "B" );;
gap> h:= CharacterTable( "31:15" );;
gap> hfusb:= PossibleClassFusions( h, b );;
gap> Length( RepresentativesFusions( h, hfusb, b ) );
2
</pre>
<div class="p"><!----></div>
We determine the correct fusion using the fact that
H is contained in a (maximal) subgroup of type Th in B.
<div class="p"><!----></div>
<pre>
gap> th:= CharacterTable( "Th" );;
gap> hfusth:= PossibleClassFusions( h, th );;
gap> thfusb:= PossibleClassFusions( th, b );;
gap> comp:= [];;
gap> for map1 in hfusth do
> for map2 in thfusb do
> AddSet( comp, CompositionMaps( map2, map1 ) );
> od;
> od;
gap> Length( comp );
2
gap> reps:= RepresentativesFusions( h, comp, b );
[ [ 1, 145, 146, 82, 82, 19, 82, 7, 19, 82, 82, 19, 7, 82, 19, 82, 82 ] ]
gap> GetFusionMap( h, b ) in reps;
true
</pre>
<div class="p"><!----></div>
<h3><a name="tth_sEc1.3">
1.3</a> SuzN3 → Suz (September 2002)</h3>
<div class="p"><!----></div>
The class fusion from the Sylow 3 normalizer into the sporadic simple group
Suz is not uniquely determined by the character tables of these groups.
<div class="p"><!----></div>
<pre>
gap> h:= CharacterTable( "SuzN3" );
CharacterTable( "3^5:(3^2:SD16)" )
gap> suz:= CharacterTable( "Suz" );
CharacterTable( "Suz" )
gap> hfussuz:= PossibleClassFusions( h, suz );;
gap> Length( RepresentativesFusions( h, hfussuz, suz ) );
2
</pre>
<div class="p"><!----></div>
Since H is not maximal in Suz, we try to factorize the fusion through
a suitable maximal subgroup.
<div class="p"><!----></div>
<pre>
gap> maxes:= List( Maxes( suz ), CharacterTable );;
gap> filt:= Filtered( maxes, x -> Size( x ) mod Size( h ) = 0 );
[ CharacterTable( "3_2.U4(3).2_3'" ), CharacterTable( "3^5:M11" ),
CharacterTable( "3^2+4:2(2^2xa4)2" ) ]
</pre>
<div class="p"><!----></div>
The group 3<sub>2</sub>.U<sub>4</sub>(3).2<sub>3</sub><sup>′</sup> does not admit a fusion from H.
<div class="p"><!----></div>
<pre>
gap> PossibleClassFusions( h, filt[1] );
[ ]
</pre>
<div class="p"><!----></div>
Definitely 3<sup>5</sup>:M<sub>11</sub> contains a group isomorphic with H,
because the Sylow 3 normalizer in M<sub>11</sub> has the structure 3<sup>2</sup>:SD<sub>16</sub>;
using 3<sup>2+4</sup>:2(2<sup>2</sup> ×A<sub>4</sub>)2 would lead to the same result as
we get below.
We compute the compositions of possible class fusions.
<div class="p"><!----></div>
<pre>
gap> max:= filt[2];;
gap> hfusmax:= PossibleClassFusions( h, max );;
gap> maxfussuz:= PossibleClassFusions( max, suz );;
gap> comp:= [];;
gap> for map1 in hfusmax do
> for map2 in maxfussuz do
> AddSet( comp, CompositionMaps( map2, map1 ) );
> od;
> od;
gap> repr:= RepresentativesFusions( h, comp, suz );
[ [ 1, 2, 2, 4, 5, 4, 5, 5, 5, 5, 5, 6, 9, 9, 14, 15, 13, 16, 16, 14, 15, 13,
13, 13, 16, 15, 14, 16, 16, 16, 21, 21, 23, 22, 29, 29, 29, 38, 39 ] ]
</pre>
<div class="p"><!----></div>
So the factorization determines the fusion map up to table automorphisms.
We check that this map is equal to the stored one.
<div class="p"><!----></div>
<pre>
gap> GetFusionMap( h, suz ) in repr;
true
</pre>
<div class="p"><!----></div>
<h3><a name="tth_sEc1.4">
1.4</a> F<sub>3+</sub>N5 → F<sub>3+</sub> (March 2002)</h3>
<div class="p"><!----></div>
The class fusion from the table of the Sylow 5 normalizer H in the
sporadic simple group F<sub>3+</sub> into F<sub>3+</sub> is ambiguous.
<div class="p"><!----></div>
<pre>
gap> f3p:= CharacterTable( "F3+" );;
gap> h:= CharacterTable( "F3+N5" );;
gap> hfusf3p:= PossibleClassFusions( h, f3p );;
gap> Length( RepresentativesFusions( h, hfusf3p, f3p ) );
2
</pre>
<div class="p"><!----></div>
H is not maximal in F<sub>3+</sub>,
so we look for tables of maximal subgroups that can contain H.
<div class="p"><!----></div>
<pre>
gap> maxes:= List( Maxes( f3p ), CharacterTable );;
gap> filt:= Filtered( maxes, x -> Size( x ) mod Size( h ) = 0 );
[ CharacterTable( "Fi23" ), CharacterTable( "2.Fi22.2" ),
CharacterTable( "(3xO8+(3):3):2" ), CharacterTable( "O10-(2)" ),
CharacterTable( "(A4xO8+(2).3).2" ), CharacterTable( "He.2" ),
CharacterTable( "F3+M14" ), CharacterTable( "(A5xA9):2" ) ]
gap> possfus:= List( filt, x -> PossibleClassFusions( h, x ) );
[ [ ], [ ], [ ], [ ],
[ [ 1, 69, 110, 12, 80, 121, 4, 72, 113, 11, 11, 79, 79, 120, 120, 3, 71,
11, 79, 23, 91, 112, 120, 132, 29, 32, 97, 100, 37, 37, 105, 105,
139, 140, 145, 146, 155, 155, 156, 156, 44, 44, 167, 167, 48, 48,
171, 171, 57, 57, 180, 180, 66, 66, 189, 189 ],
[ 1, 69, 110, 12, 80, 121, 4, 72, 113, 11, 11, 79, 79, 120, 120, 3, 71,
11, 79, 23, 91, 112, 120, 132, 29, 32, 97, 100, 37, 37, 105, 105,
140, 139, 146, 145, 156, 156, 155, 155, 44, 44, 167, 167, 48, 48,
171, 171, 57, 57, 180, 180, 66, 66, 189, 189 ] ], [ ], [ ], [ ] ]
</pre>
<div class="p"><!----></div>
We see that from the eight possible classes of maximal subgroups in F<sub>3+</sub>
that might contain H, only the group of type (A<sub>4</sub> ×O<sub>8</sub><sup>+</sup>(2).3).2
admits a class fusion from H.
Hence we can compute the compositions of the possible fusions from H into
this group with the possible fusions from this group into F<sub>3+</sub>.
<div class="p"><!----></div>
<pre>
gap> max:= filt[5];
CharacterTable( "(A4xO8+(2).3).2" )
gap> hfusmax:= possfus[5];;
gap> maxfusf3p:= PossibleClassFusions( max, f3p );;
gap> comp:= [];;
gap> for map1 in maxfusf3p do
> for map2 in hfusmax do
> AddSet( comp, CompositionMaps( map1, map2 ) );
> od;
> od;
gap> Length( comp );
2
gap> repr:= RepresentativesFusions( h, comp, f3p );
[ [ 1, 2, 4, 12, 35, 54, 3, 3, 16, 9, 9, 11, 11, 40, 40, 2, 3, 9, 11, 35, 36,
13, 40, 90, 7, 22, 19, 20, 43, 43, 50, 50, 8, 8, 23, 23, 46, 46, 47,
47, 10, 10, 9, 9, 10, 10, 11, 11, 26, 26, 28, 28, 67, 67, 68, 68 ] ]
</pre>
<div class="p"><!----></div>
Finally, we check whether the map stored in the table library is correct.
<div class="p"><!----></div>
<pre>
gap> GetFusionMap( h, f3p ) in repr;
true
</pre>
<div class="p"><!----></div>
Note that we did <b>not</b> determine the class fusion from the maximal subgroup
(A<sub>4</sub> ×O<sub>8</sub><sup>+</sup>(2).3).2 into F<sub>3+</sub> up to table automorphisms
(see Section <a href="#A4xO8p2d32fusf3p">2.1</a> for this problem),
since also the ambiguous result was enough for computing the fusion from
H into F<sub>3+</sub>.
<div class="p"><!----></div>
<h2><a name="tth_sEc2">
2</a> Fusions Determined by Commutative Diagrams Using Smaller Subgroups</h2>
<div class="p"><!----></div>
<table><tr><td width="75%">
In each of the following examples, the class fusion of a maximal subgroup M
of a group G is determined by considering a proper subgroup U of M
whose class fusion into G can be computed, perhaps using another subgroup
S of G that also contains U.
<div class="p"><!----></div>
</td><td width="25%">
<div class="p"><!----></div>
<center> <img src="ambigfus1.png" alt="ambigfus1.png" />
</center>
<div class="p"><!----></div>
</td></tr></table>
<div class="p"><!----></div>
<h3><a name="tth_sEc2.1">
2.1</a> (A<sub>4</sub> ×O<sub>8</sub><sup>+</sup>(2).3).2 → Fi<sub>24</sub><sup>′</sup>
(November 2002)</h3><a name="A4xO8p2d32fusf3p">
</a>
<div class="p"><!----></div>
The class fusion of the maximal subgroup M ≅ (A<sub>4</sub> ×O<sub>8</sub><sup>+</sup>(2).3).2
of G = Fi<sub>24</sub><sup>′</sup> is ambiguous.
<div class="p"><!----></div>
<pre>
gap> m:= CharacterTable( "(A4xO8+(2).3).2" );;
gap> t:= CharacterTable( "F3+" );;
gap> mfust:= PossibleClassFusions( m, t );;
gap> repr:= RepresentativesFusions( m, mfust, t );;
gap> Length( repr );
2
</pre>
<div class="p"><!----></div>
We first observe that the elements of order three in the normal subgroup
of type A<sub>4</sub> in M lie in the class <tt>3A</tt> of Fi<sub>24</sub><sup>′</sup>.
<div class="p"><!----></div>
<pre>
gap> a4inm:= Filtered( ClassPositionsOfNormalSubgroups( m ),
> n -> Sum( SizesConjugacyClasses( m ){ n } ) = 12 );
[ [ 1, 69, 110 ] ]
gap> OrdersClassRepresentatives( m ){ a4inm[1] };
[ 1, 2, 3 ]
gap> List( repr, map -> map[110] );
[ 4, 4 ]
gap> OrdersClassRepresentatives( t ){ [ 1 .. 4 ] };
[ 1, 2, 2, 3 ]
</pre>
<div class="p"><!----></div>
Let us take one such element g, say.
Its normalizer S in G has the structure (3 ×O<sub>8</sub><sup>+</sup>(3).3).2;
this group is maximal in G, and its character table is available in <font face="helvetica">GAP</font>.
<div class="p"><!----></div>
<pre>
gap> s:= CharacterTable( "F3+N3A" );
CharacterTable( "(3xO8+(3):3):2" )
</pre>
<div class="p"><!----></div>
The intersection N<sub>M</sub>(g) = S ∩M contains a subgroup U of the type
3 ×O<sub>8</sub><sup>+</sup>(2).3,
and in the following we compute the class fusions of U into S and M,
and then utilize the fact that only those class fusions from M into G
are possible whose composition with the class fusion from U into M
equals a composition of class fusions from U into S
and from S into G.
<div class="p"><!----></div>
<pre>
gap> u:= CharacterTable( "Cyclic", 3 ) * CharacterTable( "O8+(2).3" );
CharacterTable( "C3xO8+(2).3" )
gap> ufuss:= PossibleClassFusions( u, s );;
gap> ufusm:= PossibleClassFusions( u, m );;
gap> sfust:= PossibleClassFusions( s, t );;
gap> comp:= [];;
gap> for map1 in ufuss do
> for map2 in sfust do
> AddSet( comp, CompositionMaps( map2, map1 ) );
> od;
> od;
gap> Length( comp );
6
gap> filt:= Filtered( mfust,
> x -> ForAny( ufusm, map -> CompositionMaps( x, map ) in comp ) );;
gap> repr:= RepresentativesFusions( m, filt, t );;
gap> Length( repr );
1
gap> GetFusionMap( m, t ) in repr;
true
</pre>
<div class="p"><!----></div>
So the class fusion from M into G is determined up to table automorphisms
by the commutative diagram.
<div class="p"><!----></div>
<h3><a name="tth_sEc2.2">
2.2</a> A<sub>6</sub> ×L<sub>2</sub>(8).3 → Fi<sub>24</sub><sup>′</sup>
(November 2002)</h3>
<div class="p"><!----></div>
The class fusion of the maximal subgroup M ≅ A<sub>6</sub> ×L<sub>2</sub>(8).3
of G = Fi<sub>24</sub><sup>′</sup> is ambiguous.
<div class="p"><!----></div>
<pre>
gap> m:= CharacterTable( "A6xL2(8):3" );;
gap> t:= CharacterTable( "F3+" );;
gap> mfust:= PossibleClassFusions( m, t );;
gap> Length( RepresentativesFusions( m, mfust, t ) );
2
</pre>
<div class="p"><!----></div>
We will use the fact that the direct factor of the type A<sub>6</sub> in M
contains elements in the class <tt>3A</tt> of G.
This fact can be shown as follows.
<div class="p"><!----></div>
<pre>
gap> dppos:= ClassPositionsOfDirectProductDecompositions( m );
[ [ [ 1, 12 .. 67 ], [ 1 .. 11 ] ] ]
gap> List( dppos[1], l -> Sum( SizesConjugacyClasses( t ){ l } ) );
[ 17733424133316996808705, 4545066196775803392 ]
gap> List( dppos[1], l -> Sum( SizesConjugacyClasses( m ){ l } ) );
[ 360, 1512 ]
gap> 3Apos:= Position( OrdersClassRepresentatives( t ), 3 );
4
gap> 3Ainm:= List( mfust, map -> Position( map, 3Apos ) );
[ 23, 23, 23, 23, 34, 34, 34, 34 ]
gap> ForAll( 3Ainm, x -> x in dppos[1][1] );
true
</pre>
<div class="p"><!----></div>
Since the normalizer of an element of order three in A<sub>6</sub> has the form
3<sup>2</sup>:2,
such a <tt>3A</tt> element in M contains a subgroup U of the structure
3<sup>2</sup>:2 ×L<sub>2</sub>(8).3 which is contained in the <tt>3A</tt> normalizer S in G,
which has the structure (3 ×O<sub>8</sub><sup>+</sup>(3).3).2.
<div class="p"><!----></div>
(Note that all classes in the 3<sup>2</sup>:2 type group are rational,
and its character table is available in the <font face="helvetica">GAP</font> Character Table Library
with the identifier <tt>"3^2:2"</tt>.)
<div class="p"><!----></div>
<pre>
gap> u:= CharacterTable( "3^2:2" ) * CharacterTable( "L2(8).3" );
CharacterTable( "3^2:2xL2(8).3" )
gap> s:= CharacterTable( "F3+N3A" );
CharacterTable( "(3xO8+(3):3):2" )
gap> ufuss:= PossibleClassFusions( u, s );;
gap> comp:= [];;
gap> for map1 in sfust do
> for map2 in ufuss do
> AddSet( comp, CompositionMaps( map1, map2 ) );
> od;
> od;
gap> ufusm:= PossibleClassFusions( u, m );;
gap> filt:= Filtered( mfust,
> map -> ForAny( ufusm,
> map2 -> CompositionMaps( map, map2 ) in comp ) );;
gap> repr:= RepresentativesFusions( m, filt, t );;
gap> Length( repr );
1
gap> GetFusionMap( m, t ) in repr;
true
</pre>
<div class="p"><!----></div>
<h2><a name="tth_sEc3">
3</a> Conditions Imposed by Brauer Tables</h2>
<div class="p"><!----></div>
The examples in this section show that symmetries can be broken as soon as
the class fusions between two ordinary tables shall be compatible with
the corresponding Brauer character tables.
More precisely, we assume that the class fusion from each Brauer table
to its ordinary table is already fixed;
choosing these fusions consistently can be a nontrivial task,
solving so-called "generality problems" may require the construction
of certain modules, similar to the arguments used in <a href="#generality">3.2</a> below.
<div class="p"><!----></div>
<h3><a name="tth_sEc3.1">
3.1</a> L<sub>2</sub>(16).4 → J<sub>3</sub>.2</h3>
<div class="p"><!----></div>
It can happen that Brauer tables decide ambiguities of class fusions between
the corresponding ordinary tables.
An easy example is the class fusion of L<sub>2</sub>(16).4 into J<sub>3</sub>.2.
The ordinary tables admit four possible class fusions,
of which two are essentially different.
<div class="p"><!----></div>
<pre>
gap> s:= CharacterTable( "L2(16).4" );;
gap> t:= CharacterTable( "J3.2" );;
gap> fus:= PossibleClassFusions( s, t );
[ [ 1, 2, 3, 6, 14, 15, 16, 2, 5, 7, 12, 5, 5, 8, 8, 13, 13 ],
[ 1, 2, 3, 6, 14, 15, 16, 2, 5, 7, 12, 19, 19, 22, 22, 23, 23 ],
[ 1, 2, 3, 6, 14, 16, 15, 2, 5, 7, 12, 5, 5, 8, 8, 13, 13 ],
[ 1, 2, 3, 6, 14, 16, 15, 2, 5, 7, 12, 19, 19, 22, 22, 23, 23 ] ]
gap> RepresentativesFusions( s, fus, t );
[ [ 1, 2, 3, 6, 14, 15, 16, 2, 5, 7, 12, 5, 5, 8, 8, 13, 13 ],
[ 1, 2, 3, 6, 14, 15, 16, 2, 5, 7, 12, 19, 19, 22, 22, 23, 23 ] ]
</pre>
<div class="p"><!----></div>
Using Brauer tables, we will see that just one fusion is admissible.
<div class="p"><!----></div>
We can exclude two possible fusions by the fact that their images all
lie inside the normal subgroup J<sub>3</sub>, but J<sub>3</sub> does not contain a subgroup
of type L<sub>2</sub>(16).4; so still one orbit of length two remains.
<div class="p"><!----></div>
<pre>
gap> j3:= CharacterTable( "J3" );;
gap> PossibleClassFusions( s, j3 );
[ ]
gap> GetFusionMap( j3, t );
[ 1, 2, 3, 4, 5, 6, 6, 7, 8, 9, 10, 11, 12, 12, 13, 14, 14, 15, 16, 17, 17 ]
gap> filt:= Filtered( fus,
> x -> not IsSubset( ClassPositionsOfDerivedSubgroup( t ), x ) );
[ [ 1, 2, 3, 6, 14, 15, 16, 2, 5, 7, 12, 19, 19, 22, 22, 23, 23 ],
[ 1, 2, 3, 6, 14, 16, 15, 2, 5, 7, 12, 19, 19, 22, 22, 23, 23 ] ]
</pre>
<div class="p"><!----></div>
Now the remaining wrong fusion is excluded by the fact that the table
automorphism of J<sub>3</sub>.2 that swaps the two classes of element order 17
-which swaps two of the possible class fusions-
does not live in the 2-modular table.
<div class="p"><!----></div>
<pre>
gap> smod2:= s mod 2;;
gap> tmod2:= t mod 2;;
gap> admissible:= [];;
gap> for map in filt do
> modmap:= CompositionMaps( InverseMap( GetFusionMap( tmod2, t ) ),
> CompositionMaps( map, GetFusionMap( smod2, s ) ) );
> if not fail in Decomposition( Irr( smod2 ),
> List( Irr( tmod2 ), chi -> chi{ modmap } ), "nonnegative" ) then
> AddSet( admissible, map );
> fi;
> od;
gap> admissible;
[ [ 1, 2, 3, 6, 14, 16, 15, 2, 5, 7, 12, 19, 19, 22, 22, 23, 23 ] ]
</pre>
<div class="p"><!----></div>
The test of all available Brauer tables is implemented in the function
<tt>CTblLibTestDecompositions</tt> of the <font face="helvetica">GAP</font> Character Table Library
([<a href="#CTblLib" name="CITECTblLib">Bre04b</a>]).
<div class="p"><!----></div>
<pre>
gap> CTblLibTestDecompositions( s, fus, t ) = admissible;
true
</pre>
<div class="p"><!----></div>
We see that p-modular tables alone determine the class fusion uniquely;
in fact the primes 2 and 3 suffice for that.
<div class="p"><!----></div>
<pre>
gap> GetFusionMap( s, t ) in admissible;
true
</pre>
<div class="p"><!----></div>
<h3><a name="tth_sEc3.2">
3.2</a> L<sub>2</sub>(19) → J<sub>3</sub> (April 2003)</h3><a name="generality">
</a>
<div class="p"><!----></div>
It can happen that Brauer tables impose conditions such that ambiguities
arise which are not visible if one considers only ordinary tables.
<div class="p"><!----></div>
The class fusion between the ordinary character tables of L<sub>2</sub>(19) and J<sub>3</sub>
is unique up to table automorphisms.
<div class="p"><!----></div>
<pre>
gap> s:= CharacterTable( "L2(19)" );;
gap> t:= CharacterTable( "J3" );;
gap> sfust:= PossibleClassFusions( s, t );
[ [ 1, 2, 4, 6, 7, 10, 11, 12, 13, 14, 20, 21 ],
[ 1, 2, 4, 6, 7, 10, 11, 12, 13, 14, 21, 20 ],
[ 1, 2, 4, 6, 7, 11, 12, 10, 13, 14, 20, 21 ],
[ 1, 2, 4, 6, 7, 11, 12, 10, 13, 14, 21, 20 ],
[ 1, 2, 4, 6, 7, 12, 10, 11, 13, 14, 20, 21 ],
[ 1, 2, 4, 6, 7, 12, 10, 11, 13, 14, 21, 20 ],
[ 1, 2, 4, 7, 6, 10, 11, 12, 14, 13, 20, 21 ],
[ 1, 2, 4, 7, 6, 10, 11, 12, 14, 13, 21, 20 ],
[ 1, 2, 4, 7, 6, 11, 12, 10, 14, 13, 20, 21 ],
[ 1, 2, 4, 7, 6, 11, 12, 10, 14, 13, 21, 20 ],
[ 1, 2, 4, 7, 6, 12, 10, 11, 14, 13, 20, 21 ],
[ 1, 2, 4, 7, 6, 12, 10, 11, 14, 13, 21, 20 ] ]
gap> fusreps:= RepresentativesFusions( s, sfust, t );
[ [ 1, 2, 4, 6, 7, 10, 11, 12, 13, 14, 20, 21 ] ]
</pre>
<div class="p"><!----></div>
The Galois automorphism that permutes the three classes of element order 9
in the tables of (L<sub>2</sub>(19) and) J<sub>3</sub> does not live in characteristic 19.
For example, the unique irreducible Brauer character of degree 110
in the 19-modular table of J<sub>3</sub> is ϕ<sub>3</sub>,
and the value of this character on the class <tt>9A</tt> is <tt>-1+2y9+&4</tt>.
<div class="p"><!----></div>
<pre>
gap> tmod19:= t mod 19;
BrauerTable( "J3", 19 )
gap> deg110:= Filtered( Irr( tmod19 ), phi -> phi[1] = 110 );
[ Character( BrauerTable( "J3", 19 ), [ 110, -2, 5, 2, 2, 0, 0, 1, 0,
-2*E(9)^2+E(9)^3-E(9)^4-E(9)^5+E(9)^6-2*E(9)^7,
E(9)^2+E(9)^3-E(9)^4-E(9)^5+E(9)^6+E(9)^7,
E(9)^2+E(9)^3+2*E(9)^4+2*E(9)^5+E(9)^6+E(9)^7, -2, -2, -1, 0, 0,
E(17)+E(17)^2+E(17)^4+E(17)^8+E(17)^9+E(17)^13+E(17)^15+E(17)^16,
E(17)^3+E(17)^5+E(17)^6+E(17)^7+E(17)^10+E(17)^11+E(17)^12+E(17)^14 ] )
]
gap> 9A:= Position( OrdersClassRepresentatives( tmod19 ), 9 );
10
gap> deg110[1][ 9A ];
-2*E(9)^2+E(9)^3-E(9)^4-E(9)^5+E(9)^6-2*E(9)^7
gap> AtlasIrrationality( "-1+2y9+&4" ) = deg110[1][ 9A ];
true
</pre>
<div class="p"><!----></div>
It turns out that four of the twelve possible class fusions are not compatible
with the 19-modular tables.
<div class="p"><!----></div>
<pre>
gap> smod19:= s mod 19;
BrauerTable( "L2(19)", 19 )
gap> compatible:= [];;
gap> for map in sfust do
> comp:= CompositionMaps( InverseMap( GetFusionMap( tmod19, t ) ),
> CompositionMaps( map, GetFusionMap( smod19, s ) ) );
> rest:= List( Irr( tmod19 ), phi -> phi{ comp } );
> if not fail in Decomposition( Irr( smod19 ), rest, "nonnegative" ) then
> Add( compatible, map );
> fi;
> od;
gap> compatible;
[ [ 1, 2, 4, 6, 7, 11, 12, 10, 13, 14, 20, 21 ],
[ 1, 2, 4, 6, 7, 11, 12, 10, 13, 14, 21, 20 ],
[ 1, 2, 4, 6, 7, 12, 10, 11, 13, 14, 20, 21 ],
[ 1, 2, 4, 6, 7, 12, 10, 11, 13, 14, 21, 20 ],
[ 1, 2, 4, 7, 6, 11, 12, 10, 14, 13, 20, 21 ],
[ 1, 2, 4, 7, 6, 11, 12, 10, 14, 13, 21, 20 ],
[ 1, 2, 4, 7, 6, 12, 10, 11, 14, 13, 20, 21 ],
[ 1, 2, 4, 7, 6, 12, 10, 11, 14, 13, 21, 20 ] ]
</pre>
<div class="p"><!----></div>
Moreover, the subgroups of those table automorphisms of the ordinary tables
that leave the set of compatible fusions invariant make two orbits on this
set.
Indeed, the two orbits belong to essentially different decompositions of the
restriction of ϕ<sub>3</sub>.
<div class="p"><!----></div>
<pre>
gap> reps:= RepresentativesFusions( s, compatible, t );
[ [ 1, 2, 4, 6, 7, 11, 12, 10, 13, 14, 20, 21 ],
[ 1, 2, 4, 6, 7, 12, 10, 11, 13, 14, 20, 21 ] ]
gap> compatiblemod19:= List( reps, map -> CompositionMaps(
> InverseMap( GetFusionMap( tmod19, t ) ),
> CompositionMaps( map, GetFusionMap( smod19, s ) ) ) );
[ [ 1, 2, 4, 6, 7, 11, 12, 10, 13, 14 ],
[ 1, 2, 4, 6, 7, 12, 10, 11, 13, 14 ] ]
gap> rest:= List( compatiblemod19, map -> Irr( tmod19 )[3]{ map } );;
gap> dec:= Decomposition( Irr( smod19 ), rest, "nonnegative" );
[ [ 0, 0, 1, 2, 1, 2, 2, 1, 0, 1 ], [ 0, 2, 0, 2, 0, 1, 2, 0, 2, 1 ] ]
gap> List( Irr( smod19 ), phi -> phi[1] );
[ 1, 3, 5, 7, 9, 11, 13, 15, 17, 19 ]
</pre>
<div class="p"><!----></div>
In order to decide which class fusion is correct,
we take the matrix representation of J<sub>3</sub> that affords ϕ<sub>3</sub>,
restrict it to L<sub>2</sub>(19), which is the second maximal subgroup of J<sub>3</sub>,
and compute the composition factors.
For that, we use a representation from the A<font size="-2">TLAS</font> of Group
Representations [<a href="#AGR" name="CITEAGR">Wil</a>], and access it via the <font face="helvetica">GAP</font> package
<font face="helvetica">AtlasRep</font> ([<a href="#AtlasRep" name="CITEAtlasRep">Bre04a</a>]).
<div class="p"><!----></div>
<pre>
gap> LoadPackage( "atlasrep" );
true
gap> prog:= AtlasStraightLineProgram( "J3", "maxes", 2 );
rec( program := <straight line program>, standardization := 1,
identifier := [ "J3", "J3G1-max2W1", 1 ] )
gap> gens:= OneAtlasGeneratingSet( "J3", Characteristic, 19, Dimension, 110 );
rec( generators := [ < immutable compressed matrix 110x110 over GF(19) >,
< immutable compressed matrix 110x110 over GF(19) > ],
standardization := 1,
identifier := [ "J3", [ "J3G1-f19r110B0.m1", "J3G1-f19r110B0.m2" ], 1, 19 ]
)
gap> restgens:= ResultOfStraightLineProgram( prog.program, gens.generators );
[ < immutable compressed matrix 110x110 over GF(19) >,
< immutable compressed matrix 110x110 over GF(19) > ]
gap> module:= GModuleByMats( restgens, GF( 19 ) );;
gap> facts:= SMTX.CollectedFactors( module );;
gap> Length( facts );
7
gap> List( facts, x -> x[1].dimension );
[ 5, 7, 9, 11, 13, 15, 19 ]
gap> List( facts, x -> x[2] );
[ 1, 2, 1, 2, 2, 1, 1 ]
</pre>
<div class="p"><!----></div>
This means that there are seven pairwise nonisomorphic composition factors,
the smallest one of dimension five.
In other words, the first of the two maps is the correct one.
Let us check whether this map equals the one that is stored on the library
table.
<div class="p"><!----></div>
<pre>
gap> GetFusionMap( s, t ) = reps[1];
true
</pre>
<div class="p"><!----></div>
<h2><a name="tth_sEc4">
4</a> Fusions Determined by Information about the Groups</h2>
<div class="p"><!----></div>
In the examples in this section, character theoretic arguments do not suffice
for determining the class fusions.
So we use computations with the groups in question or information about
these groups beyond the character table,
and perhaps additionally character theoretic arguments.
<div class="p"><!----></div>
The group representations are taken from the A<font size="-2">TLAS</font> of Group
Representations [<a href="#AGR" name="CITEAGR">Wil</a>] and are accessed via the <font face="helvetica">GAP</font> package
<font face="helvetica">AtlasRep</font> ([<a href="#AtlasRep" name="CITEAtlasRep">Bre04a</a>]).
<div class="p"><!----></div>
<pre>
gap> LoadPackage( "atlasrep" );
true
</pre>
<div class="p"><!----></div>
<h3><a name="tth_sEc4.1">
4.1</a> U<sub>3</sub>(3).2 → Fi<sub>24</sub><sup>′</sup> (November 2002)</h3>
<div class="p"><!----></div>
The group G = Fi<sub>24</sub><sup>′</sup> contains a maximal subgroup H of type
U<sub>3</sub>(3).2. From the character tables of G and H, one gets a lot of
essentially different possibilities (and additionally this takes quite some
time).
We use the description of H as the normalizer in G of a U<sub>3</sub>(3) type
subgroup containing elements in the classes <tt>2B</tt>, <tt>3D</tt>, <tt>3E</tt>, <tt>4C</tt>, <tt>4C</tt>,
<tt>6J</tt>, <tt>7B</tt>, <tt>8C</tt>, and <tt>12M</tt> (see [<a href="#BN95" name="CITEBN95">BN95</a>]).
<div class="p"><!----></div>
<pre>
gap> t:= CharacterTable( "F3+" );
CharacterTable( "F3+" )
gap> s:= CharacterTable( "U3(3).2" );
CharacterTable( "U3(3).2" )
gap> tnames:= ClassNames( t, "ATLAS" );
[ "1A", "2A", "2B", "3A", "3B", "3C", "3D", "3E", "4A", "4B", "4C", "5A",
"6A", "6B", "6C", "6D", "6E", "6F", "6G", "6H", "6I", "6J", "6K", "7A",
"7B", "8A", "8B", "8C", "9A", "9B", "9C", "9D", "9E", "9F", "10A", "10B",
"11A", "12A", "12B", "12C", "12D", "12E", "12F", "12G", "12H", "12I",
"12J", "12K", "12L", "12M", "13A", "14A", "14B", "15A", "15B", "15C",
"16A", "17A", "18A", "18B", "18C", "18D", "18E", "18F", "18G", "18H",
"20A", "20B", "21A", "21B", "21C", "21D", "22A", "23A", "23B", "24A",
"24B", "24C", "24D", "24E", "24F", "24G", "26A", "27A", "27B", "27C",
"28A", "29A", "29B", "30A", "30B", "33A", "33B", "35A", "36A", "36B",
"36C", "36D", "39A", "39B", "39C", "39D", "42A", "42B", "42C", "45A",
"45B", "60A" ]
gap> OrdersClassRepresentatives( s );
[ 1, 2, 3, 3, 4, 4, 6, 7, 8, 12, 2, 4, 6, 8, 12, 12 ]
gap> sfust:= List( [ "1A", "2B", "3D", "3E", "4C", "4C", "6J", "7B", "8C",
> "12M" ], x -> Position( tnames, x ) );
[ 1, 3, 7, 8, 11, 11, 22, 25, 28, 50 ]
gap> sfust:= PossibleClassFusions( s, t, rec( fusionmap:= sfust ) );
[ [ 1, 3, 7, 8, 11, 11, 22, 25, 28, 50, 3, 9, 23, 28, 43, 43 ],
[ 1, 3, 7, 8, 11, 11, 22, 25, 28, 50, 3, 11, 23, 28, 50, 50 ] ]
gap> OrdersClassRepresentatives( s );
[ 1, 2, 3, 3, 4, 4, 6, 7, 8, 12, 2, 4, 6, 8, 12, 12 ]
</pre>
<div class="p"><!----></div>
So we still have two possibilities, which differ on the outer classes of
element order 4 and 12.
<div class="p"><!----></div>
Our idea is to take a subgroup U of H that contains such elements,
and to compute the possible class fusions of U into G, via the
factorization through a suitable maximal subgroup M of G.
<div class="p"><!----></div>
We take U = N<sub>H</sub>(〈g 〉) where g is an element in the first
class of order three elements of H;
this is a maximal subgroup of H, of order 216.
<div class="p"><!----></div>
<pre>
gap> Maxes( s );
[ "U3(3)", "3^(1+2):SD16", "L3(2).2", "2^(1+4).S3", "4^2:D12" ]
gap> SizesCentralizers( s );
[ 12096, 192, 216, 18, 96, 32, 24, 7, 8, 12, 48, 48, 6, 8, 12, 12 ]
gap> u:= CharacterTable( Maxes( s )[2] );;
gap> ufuss:= GetFusionMap( u, s );
[ 1, 2, 11, 3, 4, 5, 12, 7, 13, 9, 9, 15, 16, 10 ]
</pre>
<div class="p"><!----></div>
Candidates for M are those subgroups of G that contain elements
in the class <tt>3D</tt> of G whose centralizer is the full <tt>3D</tt> centralizer
in G.
<div class="p"><!----></div>
<pre>
gap> 3Dcentralizer:= SizesCentralizers( t )[7];
153055008
gap> cand:= [];;
gap> for name in Maxes( t ) do
> m:= CharacterTable( name );
> mfust:= GetFusionMap( m, t );
> if ForAny( [ 1 .. Length( mfust ) ],
> i -> mfust[i] = 7 and SizesCentralizers( m )[i] = 3Dcentralizer )
> then
> Add( cand, m );
> fi;
> od;
gap> cand;
[ CharacterTable( "3^7.O7(3)" ), CharacterTable( "3^2.3^4.3^8.(A5x2A4).2" ) ]
</pre>
<div class="p"><!----></div>
For these two groups M, we show that the possible class fusions from U
to G via M factorize through H only if the second possible class fusion
from H to G is chosen.
<div class="p"><!----></div>
<pre>
gap> possufust:= List( sfust, x -> CompositionMaps( x, ufuss ) );
[ [ 1, 3, 3, 7, 8, 11, 9, 22, 23, 28, 28, 43, 43, 50 ],
[ 1, 3, 3, 7, 8, 11, 11, 22, 23, 28, 28, 50, 50, 50 ] ]
gap> m:= cand[1];;
gap> ufusm:= PossibleClassFusions( u, m );;
gap> Length( ufusm );
242
gap> comp:= List( ufusm, x -> CompositionMaps( GetFusionMap( m, t ), x ) );;
gap> Intersection( possufust, comp );
[ [ 1, 3, 3, 7, 8, 11, 11, 22, 23, 28, 28, 50, 50, 50 ] ]
gap> m:= cand[2];;
gap> ufusm:= PossibleClassFusions( u, m );;
gap> Length( ufusm );
256
gap> comp:= List( ufusm, x -> CompositionMaps( GetFusionMap( m, t ), x ) );;
gap> Intersection( possufust, comp );
[ [ 1, 3, 3, 7, 8, 11, 11, 22, 23, 28, 28, 50, 50, 50 ] ]
</pre>
<div class="p"><!----></div>
Finally, we check that the correct fusion is stored in the <font face="helvetica">GAP</font> Character
Table Library.
<div class="p"><!----></div>
<pre>
gap> GetFusionMap( s, t ) = sfust[2];
true
</pre>
<div class="p"><!----></div>
<div class="p"><!----></div>
<h3><a name="tth_sEc4.2">
4.2</a> L<sub>2</sub>(13).2 → Fi<sub>24</sub><sup>′</sup> (September 2002)</h3>
<div class="p"><!----></div>
The class fusion of maximal subgroups U of type L<sub>2</sub>(13).2
in G = Fi<sub>24</sub><sup>′</sup> is ambiguous.
<div class="p"><!----></div>
<pre>
gap> t:= CharacterTable( "F3+" );;
gap> u:= CharacterTable( "L2(13).2" );;
gap> fus:= PossibleClassFusions( u, t );;
gap> repr:= RepresentativesFusions( u, fus, t );;
gap> Length( repr );
3
</pre>
<div class="p"><!----></div>
In [<a href="#LW91" name="CITELW91">LW91</a>,p. 155], it is stated that U<sup>′</sup> contains elements
in the classes <tt>2B</tt>, <tt>3D</tt>, and <tt>7B</tt> of G.
(Note that the two conjugacy classes of groups isomorphic to U have
the same class fusion because the outer automorphism of G fixes
the relevant classes.)
<div class="p"><!----></div>
<pre>
gap> filt:= Filtered( repr, x -> t.2b in x and t.3d in x and t.7b in x );
[ [ 1, 3, 7, 22, 25, 25, 25, 51, 3, 9, 43, 43, 53, 53, 53 ],
[ 1, 3, 7, 22, 25, 25, 25, 51, 3, 11, 50, 50, 53, 53, 53 ] ]
gap> ClassNames( t ){ [ 43, 50 ] };
[ "12f", "12m" ]
</pre>
<div class="p"><!----></div>
So we have to decide whether U contains elements in the class <tt>12F</tt> or
in <tt>12M</tt> of G.
<div class="p"><!----></div>
The order 12 elements in question lie inside subgroups of type 13 : 12
in U.
These subgroups are clearly contained in the Sylow 13 normalizers of G,
which are contained in maximal subgroups of type (3<sup>2</sup>:2 ×G<sub>2</sub>(3)).2
in G;
the class fusion of the latter groups is unique up to table automorphisms.
<div class="p"><!----></div>
<pre>
gap> pos:= Position( OrdersClassRepresentatives( t ), 13 );
51
gap> SizesCentralizers( t )[ pos ];
234
gap> ClassOrbit( t, pos );
[ 51 ]
gap> cand:= [];;
gap> for name in Maxes( t ) do
> m:= CharacterTable( name );
> pos:= Position( OrdersClassRepresentatives( m ), 13 );
> if pos <> fail and
> SizesCentralizers( m )[ pos ] = 234
> and ClassOrbit( m, pos ) = [ pos ] then
> Add( cand, m );
> fi;
> od;
gap> cand;
[ CharacterTable( "(3^2:2xG2(3)).2" ) ]
gap> s:= cand[1];;
gap> sfust:= PossibleClassFusions( s, t );;
</pre>
<div class="p"><!----></div>
As no 13:12 type subgroup is contained in the derived subgroup of
(3<sup>2</sup>:2 ×G<sub>2</sub>(3)).2, we look at the elements of order 12 in the
outer half.
<div class="p"><!----></div>
<pre>
gap> der:= ClassPositionsOfDerivedSubgroup( s );;
gap> outer:= Difference( [ 1 .. NrConjugacyClasses( s ) ], der );;
gap> sfust:= PossibleClassFusions( s, t );;
gap> imgs:= Set( Flat( List( sfust, x -> x{ outer } ) ) );
[ 2, 3, 10, 11, 15, 17, 18, 19, 21, 22, 26, 44, 45, 49, 50, 52, 62, 83, 87,
98 ]
gap> t.12f in imgs;
false
gap> t.12m in imgs;
true
</pre>
<div class="p"><!----></div>
So L<sub>2</sub>(13).2 \L<sub>2</sub>(13) does not contain <tt>12F</tt> elements of G,
i. e., we have determined the class fusion of U in G.
<div class="p"><!----></div>
Finally, we check whether the correct fusion is stored in the
<font face="helvetica">GAP</font> Character Table Library.
<div class="p"><!----></div>
<pre>
gap> GetFusionMap( u, t ) = filt[2];
true
</pre>
<div class="p"><!----></div>
<h3><a name="tth_sEc4.3">
4.3</a> L<sub>2</sub>(17).2 → B (March 2004)</h3>
<div class="p"><!----></div>
The sporadic simple group B contains a maximal subgroup U of the type
L<sub>2</sub>(17).2 whose class fusion is ambiguous.
<div class="p"><!----></div>
<pre>
gap> b:= CharacterTable( "B" );;
gap> u:= CharacterTable( "L2(17).2" );;
gap> ufusb:= PossibleClassFusions( u, b );
[ [ 1, 5, 7, 15, 42, 42, 47, 47, 47, 91, 4, 30, 89, 89, 89, 89, 97, 97, 97 ],
[ 1, 5, 7, 15, 44, 44, 46, 46, 46, 91, 5, 29, 90, 90, 90, 90, 96, 96, 96 ],
[ 1, 5, 7, 15, 44, 44, 47, 47, 47, 91, 5, 29, 90, 90, 90, 90, 95, 95, 95 ] ]
</pre>
<div class="p"><!----></div>
According to [<a href="#Wil99" name="CITEWil99">Wil99</a>,Prop. 11.1], U contains elements in the classes
<tt>8M</tt> and <tt>9A</tt> of B.
This determines the fusion map.
<div class="p"><!----></div>
<pre>
gap> names:= ClassNames( b, "ATLAS" );;
gap> pos:= List( [ "8M", "9A" ], x -> Position( names, x ) );
[ 44, 46 ]
gap> ufusb:= Filtered( ufusb, map -> IsSubset( map, pos ) );
[ [ 1, 5, 7, 15, 44, 44, 46, 46, 46, 91, 5, 29, 90, 90, 90, 90, 96, 96, 96 ] ]
</pre>
<div class="p"><!----></div>
We check that this map is stored on the lilbrary table.
<div class="p"><!----></div>
<pre>
gap> GetFusionMap( u, b ) = ufusb[1];
true
</pre>
<div class="p"><!----></div>
<h3><a name="tth_sEc4.4">
4.4</a> 2<sup>3</sup>.L<sub>3</sub>(2) → G<sub>2</sub>(5)</h3>
<div class="p"><!----></div>
The Chevalley group G = G<sub>2</sub>(5) contains a maximal subgroup U of the type
2<sup>3</sup>.L<sub>3</sub>(2) whose class fusion is ambiguous.
<div class="p"><!----></div>
<pre>
gap> t:= CharacterTable( "G2(5)" );;
gap> s:= CharacterTable( "2^3.L3(2)" );;
gap> sfust:= PossibleClassFusions( s, t );;
gap> RepresentativesFusions( s, sfust, t );
[ [ 1, 2, 2, 5, 6, 4, 13, 16, 17, 15, 15 ],
[ 1, 2, 2, 5, 6, 4, 14, 16, 17, 15, 15 ] ]
</pre>
<div class="p"><!----></div>
So the question is whether U contains elements in the class <tt>6B</tt> or <tt>6C</tt>
of G (position 13 or 14 in the A<font size="-2">TLAS</font> table).
We use a permutation representation of G, restrict it to U,
and compute the centralizer in G of an element of order 6 in U.
<div class="p"><!----></div>
<pre>
gap> gens:= OneAtlasGeneratingSet( "G2(5)" );;
gap> g:= Group( gens.generators );;
gap> prg:= AtlasStraightLineProgram( "G2(5)", "maxes", 7 );;
gap> subgens:= ResultOfStraightLineProgram( prg.program, gens.generators );;
gap> u:= Group( gens.generators );;
gap> repeat
> x:= Random( u );
> until Order( x ) = 6;
gap> siz:= Size( Centralizer( g, x ) );
36
gap> Filtered( [ 1 .. NrConjugacyClasses( t ) ],
> i -> SizesCentralizers( t )[i] = siz );
[ 14 ]
</pre>
<div class="p"><!----></div>
So U contains <tt>6C</tt> elements in G<sub>2</sub>(5).
<div class="p"><!----></div>
<pre>
gap> GetFusionMap( s, t ) in Filtered( sfust, map -> 14 in map );
true
</pre>
<div class="p"><!----></div>
<h3><a name="tth_sEc4.5">
4.5</a> The fusion from the character table of 7<sup>2</sup>:2L<sub>2</sub>(7).2
into the table of marks</h3>
<div class="p"><!----></div>
It can happen that the class fusion from the ordinary character table of a
group G into the table of marks of G is not unique up to table
automorphisms of the character table of G.
<div class="p"><!----></div>
As an example, consider G = 7<sup>2</sup>:2L<sub>2</sub>(7).2, a maximal subgroup in the
sporadic simple group He.
<div class="p"><!----></div>
G contains four classes of cyclic subgroups of order 7.
One contains the elements in the normal subgroup of type 7<sup>2</sup>,
and the other three are preimages of the order 7 elements in the
factor group L<sub>2</sub>(7).
The conjugacy classes of nonidentity elements in the latter three classes
split into two Galois conjugates each, which are permuted cyclicly by the
table automorphisms of the character table of G,
but on which the stabilizer of one class acts trivially.
This means that determining one of the three classes determines also the
other two.
<div class="p"><!----></div>
<pre>
gap> tbl:= CharacterTable( "7^2:2psl(2,7)" );
CharacterTable( "7^2:2psl(2,7)" )
gap> tom:= TableOfMarks( FusionToTom( tbl ).name );
TableOfMarks( "7^2:2L2(7)" )
gap> fus:= PossibleFusionsCharTableTom( tbl, tom );
[ [ 1, 6, 2, 4, 3, 5, 13, 13, 7, 8, 10, 9, 16, 7, 10, 9, 8, 16 ],
[ 1, 6, 2, 4, 3, 5, 13, 13, 7, 9, 8, 10, 16, 7, 8, 10, 9, 16 ],
[ 1, 6, 2, 4, 3, 5, 13, 13, 7, 10, 9, 8, 16, 7, 9, 8, 10, 16 ],
[ 1, 6, 2, 4, 3, 5, 13, 13, 7, 8, 9, 10, 16, 7, 9, 10, 8, 16 ],
[ 1, 6, 2, 4, 3, 5, 13, 13, 7, 10, 8, 9, 16, 7, 8, 9, 10, 16 ],
[ 1, 6, 2, 4, 3, 5, 13, 13, 7, 9, 10, 8, 16, 7, 10, 8, 9, 16 ] ]
gap> reps:= RepresentativesFusions( tbl, fus, Group(()) );
[ [ 1, 6, 2, 4, 3, 5, 13, 13, 7, 8, 9, 10, 16, 7, 9, 10, 8, 16 ],
[ 1, 6, 2, 4, 3, 5, 13, 13, 7, 8, 10, 9, 16, 7, 10, 9, 8, 16 ] ]
gap> AutomorphismsOfTable( tbl );
Group([ (9,14)(10,17)(11,15)(12,16)(13,18), (7,8), (10,11,12)(15,16,17) ])
gap> OrdersClassRepresentatives( tbl );
[ 1, 7, 2, 4, 3, 6, 8, 8, 7, 7, 7, 7, 14, 7, 7, 7, 7, 14 ]
gap> perms1:= PermCharsTom( reps[1], tom );;
gap> perms2:= PermCharsTom( reps[2], tom );;
gap> perms1 = perms2;
false
gap> Set( perms1 ) = Set( perms2 );
true
</pre>
<div class="p"><!----></div>
The table of marks of G does not distinguish the three classes
of cyclic subgroups,
there are permutations of rows and columns that act as an S<sub>3</sub> on them.
<div class="p"><!----></div>
Note that an S<sub>3</sub> acts on the classes in question in the <b>rational</b>
character table.
So it is due to the irrationalities in the character table that it
contains more information.
<div class="p"><!----></div>
<pre>
gap> Display( tbl );
7^2:2psl(2,7)
2 4 . 4 3 1 1 3 3 1 . . . 1 1 . . . 1
3 1 . 1 . 1 1 . . . . . . . . . . . .
7 3 3 1 . . . . . 2 2 2 2 1 2 2 2 2 1
1a 7a 2a 4a 3a 6a 8a 8b 7b 7c 7d 7e 14a 7f 7g 7h 7i 14b
2P 1a 7a 1a 2a 3a 3a 4a 4a 7b 7c 7d 7e 7b 7f 7g 7h 7i 7f
3P 1a 7a 2a 4a 1a 2a 8b 8a 7f 7i 7g 7h 14b 7b 7d 7e 7c 14a
5P 1a 7a 2a 4a 3a 6a 8b 8a 7f 7i 7g 7h 14b 7b 7d 7e 7c 14a
7P 1a 1a 2a 4a 3a 6a 8a 8b 1a 1a 1a 1a 2a 1a 1a 1a 1a 2a
11P 1a 7a 2a 4a 3a 6a 8b 8a 7b 7c 7d 7e 14a 7f 7g 7h 7i 14b
13P 1a 7a 2a 4a 3a 6a 8b 8a 7f 7i 7g 7h 14b 7b 7d 7e 7c 14a
X.1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1 1
X.2 3 3 3 -1 . . 1 1 B B B B B /B /B /B /B /B
X.3 3 3 3 -1 . . 1 1 /B /B /B /B /B B B B B B
X.4 6 6 6 2 . . . . -1 -1 -1 -1 -1 -1 -1 -1 -1 -1
X.5 7 7 7 -1 1 1 -1 -1 . . . . . . . . . .
X.6 8 8 8 . -1 -1 . . 1 1 1 1 1 1 1 1 1 1
X.7 4 4 -4 . 1 -1 . . -B -B -B -B B -/B -/B -/B -/B /B
X.8 4 4 -4 . 1 -1 . . -/B -/B -/B -/B /B -B -B -B -B B
X.9 6 6 -6 . . . A -A -1 -1 -1 -1 1 -1 -1 -1 -1 1
X.10 6 6 -6 . . . -A A -1 -1 -1 -1 1 -1 -1 -1 -1 1
X.11 8 8 -8 . -1 1 . . 1 1 1 1 -1 1 1 1 1 -1
X.12 48 -1 . . . . . . 6 -1 -1 -1 . 6 -1 -1 -1 .
X.13 48 -1 . . . . . . C -1 /C /D . /C C D -1 .
X.14 48 -1 . . . . . . C /C /D -1 . /C D -1 C .
X.15 48 -1 . . . . . . /C D -1 C . C -1 /C /D .
X.16 48 -1 . . . . . . C /D -1 /C . /C -1 C D .
X.17 48 -1 . . . . . . /C C D -1 . C /D -1 /C .
X.18 48 -1 . . . . . . /C -1 C D . C /C /D -1 .
A = E(8)-E(8)^3
= ER(2) = r2
B = E(7)+E(7)^2+E(7)^4
= (-1+ER(-7))/2 = b7
C = 2*E(7)+2*E(7)^2+2*E(7)^4
= -1+ER(-7) = 2b7
D = -3*E(7)-3*E(7)^2-2*E(7)^3-3*E(7)^4-2*E(7)^5-2*E(7)^6
= (5-ER(-7))/2 = 2-b7
gap> mat:= MatTom( tom );;
gap> mataut:= MatrixAutomorphisms( mat );;
gap> Print( mataut, "\n" );
Group( [ (11,12)(23,24)(27,28)(46,47)(53,54)(56,57),
( 9,10)(20,21)(31,32)(38,39), ( 8, 9)(20,22)(31,33)(38,40) ] )
gap> RepresentativesFusions( Group( () ), reps, mataut );
[ [ 1, 6, 2, 4, 3, 5, 13, 13, 7, 8, 9, 10, 16, 7, 9, 10, 8, 16 ] ]
</pre>
<div class="p"><!----></div>
We could say that thus the fusion is unique up to table automorphisms
and automorphisms of the table of marks.
But since a group is associated with the table of marks,
we compute the character table from the group,
and decide which class fusion is correct.
<div class="p"><!----></div>
<pre>
gap> g:= UnderlyingGroup( tom );;
gap> tg:= CharacterTable( g );;
gap> tgfustom:= FusionCharTableTom( tg, tom );
[ 1, 6, 2, 3, 5, 16, 7, 8, 10, 9, 7, 8, 10, 9, 16, 4, 13, 13 ]
gap> trans:= TransformingPermutationsCharacterTables( tg, tbl );;
gap> tblfustom:= Permuted( tgfustom, trans.columns );
[ 1, 6, 2, 4, 3, 5, 13, 13, 7, 8, 10, 9, 16, 7, 10, 9, 8, 16 ]
gap> orbits:= List( reps, map -> OrbitFusions( AutomorphismsOfTable( tbl ),
> map, Group( () ) ) );;
gap> PositionProperty( orbits, orb -> tblfustom in orb );
2
gap> PositionProperty( orbits, orb -> FusionToTom( tbl ).map in orb );
2
</pre>
<div class="p"><!----></div>
So we see that the second one of the possibilities above is the right one.
<div class="p"><!----></div>
<h2>References</h2>
<dl compact="compact">
<dt><a href="#CITEBN95" name="BN95">[BN95]</a></dt><dd>
Thomas Breuer and Simon P. Norton, <em>Improvements to the Atlas</em>, London
Math. Soc. Monographs, vol. 11, pp. 297-327, Oxford University Press, 1995.
<div class="p"><!----></div>
</dd>
<dt><a href="#CITEAtlasRep" name="AtlasRep">[Bre04a]</a></dt><dd>
Thomas Breuer, <em>Manual for the <font face="helvetica">GAP</font> 4 Package AtlasRep, Version 1.2</em>,
Lehrstuhl D für Mathematik, Rheinisch
Westfälische Technische Hochschule, Aachen, Germany,
2004.
<div class="p"><!----></div>
</dd>
<dt><a href="#CITECTblLib" name="CTblLib">[Bre04b]</a></dt><dd>
Thomas Breuer, <em>Manual for the <font face="helvetica">GAP</font> Character Table Library, Version
1.1</em>, Lehrstuhl D für Mathematik, Rheinisch
Westfälische Technische Hochschule, Aachen, Germany,
2004.
<div class="p"><!----></div>
</dd>
<dt><a href="#CITECCN85" name="CCN85">[CCN<sup>+</sup>85]</a></dt><dd>
J[ohn] H. Conway, R[obert] T. Curtis, S[imon] P. Norton, R[ichard] A. Parker,
and R[obert] A. Wilson, <em>Atlas of finite groups</em>, Oxford University
Press, 1985.
<div class="p"><!----></div>
</dd>
<dt><a href="#CITEGAP4" name="GAP4">[GAP04]</a></dt><dd>
The GAP Group, <em>GAP - Groups, Algorithms, and Programming, Version
4.4</em>, 2004, <a href="http://www.gap-system.org"><tt>http://www.gap-system.org</tt></a>.
<div class="p"><!----></div>
</dd>
<dt><a href="#CITELW91" name="LW91">[LW91]</a></dt><dd>
Stephen A. Linton and Robert A. Wilson, <em>The maximal subgroups of the
Fischer groups Fi<sub>24</sub> and Fi<sup>′</sup><sub>24</sub></em>, Proc. London Math.
Soc. (3) <b>63</b> (1991), no. 1, 113-164.
<div class="p"><!----></div>
</dd>
<dt><a href="#CITEAGR" name="AGR">[Wil]</a></dt><dd>
Robert A. Wilson, <em>ATLAS of Finite Group Representations</em>,
<a href="http://www.mat.bham.ac.uk/atlas/"><tt>http://www.mat.bham.ac.uk/atlas/</tt></a>.
<div class="p"><!----></div>
</dd>
<dt><a href="#CITEWil99" name="Wil99">[Wil99]</a></dt><dd>
Robert A. Wilson, <em>The maximal subgroups of the Baby Monster, I</em>, J.
Algebra <b>211</b> (1999), 1-14.</dd>
</dl>
<div class="p"><!----></div>
<div class="p"><!----></div>
<br /><br /><hr /><small>File translated from
T<sub><font size="-1">E</font></sub>X
by <a href="http://hutchinson.belmont.ma.us/tth/">
T<sub><font size="-1">T</font></sub>H</a>,
version 3.55.<br />On 31 Mar 2004, 10:53.</small>
</html>
distrib
>
Mandriva
>
2010.0
>
i586
>
media
>
contrib-release
>
by-pkgid
>
5e1854624d3bc613bdd0dd13d1ef9ac7
>
files
>
1159
