#
# Package managment
#

body common control
{
bundlesequence => { "packages" };
}

#############################################

bundle agent packages
{
vars:

 "exact_package" slist => { 
                          "apache2", 
                          "kernel-default" 
                          };

 "version[OpenOffice_org-hyphen]" string => "1.2.3";
 "version[kernel-default]"        string => "2.6.27.7-9.1";

packages:

  "$(exact_package)"

     package_policy => "verify",
     package_method => rpm,
     package_select => ">=",
     package_architectures => { "x86_64" },
     package_version => "$(version[$(exact_package)])";

}

#############################################

body package_method rpm

{
any::

 package_changes => "individual";

 package_list_command => "/bin/rpm -qa --queryformat \"i | repos | %{name} | %{version}-%{release} | %{arch}\n\"";

 # Remember to escape special characters like |

 package_list_name_regex    => "[^|]+\|[^|]+\|\s+([^\s|]+).*";
 package_list_version_regex => "[^|]+\|[^|]+\|[^|]+\|\s+([^\s|]+).*";
 package_list_arch_regex    => "[^|]+\|[^|]+\|[^|]+\|[^|]+\|\s+([^\s]+).*";

 package_installed_regex => "i.*";

package_name_convention => "$(name).$(arch)";

package_add_command => "/bin echo /bin/rpm -i ";
package_delete_command => "/bin/rpm -e --nodeps";
package_verify_command => "/bin/rpm -V";
package_noverify_regex => ".*[^\s].*";
#package_noverify_returncode => "-1";

}