5 Constructing numerical semigroups from others
  
  
  5.1 Adding and removing elements of a numerical semigroup
  
  In  this  section  we  show how to construct new numerical semigroups from a
  given  numerical semigroup. Two dual operations are presented. The first one
  removes  a  minimal  generator from a numerical semigroup. The second adds a
  special gap to a semigroup (see [GJ03]).
  
  5.1-1 RemoveMinimalGeneratorFromNumericalSemigroup
  
  > RemoveMinimalGeneratorFromNumericalSemigroup( n, S ) _____________function
  
  S is a numerical semigroup and n is one if its minimal generators.
  
  The  output  is  the  numerical  semigroup  S  \{n}  (see [GJ03]; S\{n} is a
  numerical semigroup if and only if n is a minimal generator of S).
  
  ---------------------------  Example  ----------------------------
    gap> s:=NumericalSemigroup(3,5,7);
    <Numerical semigroup with 3 generators>
    gap> RemoveMinimalGeneratorFromNumericalSemigroup(7,s);
    <Numerical semigroup with 3 generators>
    gap> MinimalGeneratingSystemOfNumericalSemigroup(last);
    [ 3, 5 ]
    
                            
  ------------------------------------------------------------------
  
  5.1-2 AddSpecialGapOfNumericalSemigroup
  
  > AddSpecialGapOfNumericalSemigroup( g, S ) ________________________function
  
  S is a numerical semigroup and g is a special gap of S
  
  The  output  is  the  numerical  semigroup S cup{g} (see [GJ03], where it is
  explained why this set is a numerical semigroup).
  
  ---------------------------  Example  ----------------------------
    gap> s:=NumericalSemigroup(3,5,7);
    <Numerical semigroup with 3 generators>
    gap> s2:=RemoveMinimalGeneratorFromNumericalSemigroup(5,s);
    <Numerical semigroup with 3 generators>
    gap> s3:=AddSpecialGapOfNumericalSemigroup(5,s2);
    <Numerical semigroup>
    gap> SmallElementsOfNumericalSemigroup(s) =
    > SmallElementsOfNumericalSemigroup(s3);
    true                
    gap> s=s3;
    true
    
                            
  ------------------------------------------------------------------
  
  5.1-3 IntersectionOfNumericalSemigroups
  
  > IntersectionOfNumericalSemigroups( S, T ) ________________________function
  
  S  and  T  are  numerical  semigroups.  Computes the intersection of S and T
  (which is a numerical semigroup).
  
  ---------------------------  Example  ----------------------------
    gap> S := NumericalSemigroup("modular", 5,53);
    <Modular numerical semigroup satisfying 5x mod 53 <= x >
    gap> T := NumericalSemigroup(2,17);
    <Numerical semigroup with 2 generators>
    gap> SmallElementsOfNumericalSemigroup(S);
    [ 0, 11, 12, 13, 22, 23, 24, 25, 26, 32, 33, 34, 35, 36, 37, 38, 39, 43 ]
    gap> SmallElementsOfNumericalSemigroup(T);
    [ 0, 2, 4, 6, 8, 10, 12, 14, 16 ]
    gap> IntersectionOfNumericalSemigroups(S,T);
    <Numerical semigroup>
    gap> SmallElementsOfNumericalSemigroup(last);
    [ 0, 12, 22, 23, 24, 25, 26, 32, 33, 34, 35, 36, 37, 38, 39, 43 ]
  ------------------------------------------------------------------
  
  5.1-4 QuotientOfNumericalSemigroup
  
  > QuotientOfNumericalSemigroup( S, n ) _____________________________function
  
  S  is  a numerical semigroup and n is an integer. Computes the quotient of S
  by  n,  that  is,  the  set  {  xin N | nx in S}, which is again a numerical
  semigroup.  S / n may be used as a short for QuotientOfNumericalSemigroup(S,
  n).
  
  ---------------------------  Example  ----------------------------
    gap> s:=NumericalSemigroup(3,29);
    <Numerical semigroup with 2 generators>
    gap> SmallElementsOfNumericalSemigroup(s);
    [ 0, 3, 6, 9, 12, 15, 18, 21, 24, 27, 29, 30, 32, 33, 35, 36, 38, 
      39, 41, 42, 44, 45, 47, 48, 50, 51, 53, 54, 56 ]
    gap> t:=QuotientOfNumericalSemigroup(s,7);
    <Numerical semigroup>
    gap> SmallElementsOfNumericalSemigroup(t);
    [ 0, 3, 5, 6, 8 ]
    gap> u := s / 7;
    <Numerical semigroup>
    gap> SmallElementsOfNumericalSemigroup(u);
    [ 0, 3, 5, 6, 8 ]
  ------------------------------------------------------------------
  
  
  5.2  Constructing  the  set  of  all numerical semigroups containing a given
  numerical semigroup
  
  In  order  to  construct  the set of numerical semigroups containing a fixed
  numerical  semigroup S, one first constructs its unitary extensions, that is
  to  say,  the  sets  Scup{g} that are numerical semigroups with g a positive
  integer. This is achieved by constructing the special gaps of the semigroup,
  and  then adding each of them to the numerical semigroup. Then we repeat the
  process for each of this new numerical semigroups until we reach N.
  
  These procedures are described in [GJ03].
  
  5.2-1 OverSemigroupsNumericalSemigroup
  
  > OverSemigroupsNumericalSemigroup( s ) ____________________________function
  
  s  is  a  numerical semigroup. The output is the set of numerical semigroups
  containing it.
  
  ---------------------------  Example  ----------------------------
    gap> OverSemigroupsNumericalSemigroup(NumericalSemigroup(3,5,7));
    [ <Numerical semigroup with 1 generators>, <Numerical semigroup>,
      <Numerical semigroup>, <Numerical semigroup with 3 generators> ]
    gap> List(last,s->MinimalGeneratingSystemOfNumericalSemigroup(s));
    [ [ 1 ], [ 3, 4, 5 ], [ 2, 3 ], [ 3, 5, 7 ] ]
  ------------------------------------------------------------------
  
  5.2-2 NumericalSemigroupsWithFrobeniusNumber
  
  > NumericalSemigroupsWithFrobeniusNumber( f ) ______________________function
  
  f  is an non zero integer greater than or equal to -1. The output is the set
  of  numerical  semigroups with Frobenius number f. The algorithm implemented
  is given in [GM04].
  
  ---------------------------  Example  ----------------------------
    gap> Length(NumericalSemigroupsWithFrobeniusNumber(20));
    900
    
                            
  ------------------------------------------------------------------
  
  Given  a  numerical  semigroup  of genus g, removing minimal generators, one
  obtains numerical semigroups of genus g+1. In order to avoid repetitions, we
  only  remove  minimal  generators  greater  than the frobenius number of the
  numerical semigroup (this is accomplished with the local function sons).
  
  These procedures are described in [GB03] and [Bra08].
  
  5.2-3 NumericalSemigroupsWithGenus
  
  > NumericalSemigroupsWithGenus( g ) ________________________________function
  
  g  is  a  nonnegative integer. The output is the set of numerical semigroups
  with genusg .
  
  ---------------------------  Example  ----------------------------
    gap> NumericalSemigroupsWithGenus(5);
    [ <Numerical semigroup with 6 generators>, 
      <Numerical semigroup with 5 generators>, 
      <Numerical semigroup with 5 generators>, 
      <Numerical semigroup with 5 generators>, 
      <Numerical semigroup with 5 generators>, 
      <Numerical semigroup with 4 generators>, 
      <Numerical semigroup with 4 generators>, 
      <Numerical semigroup with 4 generators>, 
      <Numerical semigroup with 4 generators>, 
      <Numerical semigroup with 3 generators>, 
      <Numerical semigroup with 3 generators>, 
      <Numerical semigroup with 2 generators> ]
    gap> List(last,s->MinimalGeneratingSystemOfNumericalSemigroup(s));
    [ [ 6, 7, 8, 9, 10, 11 ], [ 5, 7, 8, 9, 11 ], [ 5, 6, 8, 9 ], [ 5, 6, 7, 9 ], 
      [ 5, 6, 7, 8 ], [ 4, 6, 7 ], [ 4, 7, 9, 10 ], [ 4, 6, 9, 11 ], 
      [ 4, 5, 11 ], [ 3, 8, 10 ], [ 3, 7, 11 ], [ 2, 11 ] ]
  ------------------------------------------------------------------